컴퓨터이름IP변경v1
| 첨부 '1' |
|---|
@echo off
goto StartConfig
:StartConfig
cls
REM ------------------------------------- Computer IP Setting -----------------------------------------------
SET IPx3=192.168.0.
:: 아이피 대역 앞 세구간 입력하세요. 끝에 "점" 필수 입력
SET IPxN=100
:: 아이피 카운터 시작 숫자 (예) PC 1번의 아이피 끝자리가 101 경우 100 입력하세요
SET SUBNETMASK=255.255.255.0
SET GATEWAY=192.168.0.1
SET DNS1=168.126.63.1
SET DNS2=168.126.63.2
:: 서브넷마스크, 게이트웨이, DNS 입력.
SET NICName=로컬 영역 연결
:: 랜카드 이름 (예) 로컬 영역 연결 1 ~ 또는 Local Area Connetion
SET COMName=PC-
:: 컴퓨터 이름 입력, 반복 될 앞 명칭
REM ---------------------------------------------------------------------------------------------------------
ECHO.
ECHO.
SET /p IPxNP="PC 번호를 입력하세요. >>>> "
ECHO.
SET /a IPxNT=%IPxN%+%IPxNP%
cls
ECHO.
ECHO 전체 컴퓨터 이름 : %COMName%%IPxNP%
ECHO.
ECHO IP : %IPx3%%IPxNT%
ECHO.
ECHO SUBNETMASTK : %SUBNETMASK%
ECHO.
ECHO GATEWAY : %GATEWAY%
ECHO.
ECHO DNS1 : %DNS1%
ECHO.
ECHO DNS2 : %DNS2%
ECHO.
ECHO.
goto QA
echo.
:QA
ECHO.
ECHO.
SET /p qa="설정된 정보가 위와 동일합니까? (Y/N and Defualt is Yes) >>>> "
if /i %qa%==y goto Exec
if /i %qa%==n goto StartConfig
goto Exec
echo.
:Exec
ECHO.
ECHO Starting Config....
ECHO.
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v Hostname /t REG_SZ /d %COMName%%IPxNP% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d %COMName%%IPxNP% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d %COMName%%IPxNP% > nul
ECHO.
echo 컴퓨터 이름이 %COMName%%IPxNP% 으로 변경되었습니다.
ECHO.
ECHO.
ECHO %IPxNP%번 PC의 IP 정보를 입력하고 있습니다...
ECHO.
netsh interface ip set address "%NICName%" static %IPx3%%IPxNT% %SUBNETMASK% %GATEWAY% 1
ECHO.
ECHO %IPxNP%번 PC의 DNS1 정보를 입력하고 있습니다...
ECHO.
netsh interface ip set dns name="%NICName%" source=static addr=%DNS1% register=PRIMARY
ECHO.
ECHO %IPxNP%번 PC의 DNS2 정보를 입력하고 있습니다...
ECHO.
netsh interface ip add dns name="%NICName%" addr=%DNS2% index=2
ECHO.
ECHO.
PAUSE
goto End
echo.
:End
exit
echo.
