CASZONE X-TOOLS v4.3 (Win10, Win7)
첨부 '2' |
---|
네워크 정보는 사용자 환경에 맞게 수정하여 사용바랍니다.
----- Computer IP Setting -----
SET SUBNETMASK= 수정필요
SET GATEWAY= 수정 금지!
SET DNS1= 수정필요
SET DNS2= 수정필요
SET NICName= 수정필요
@echo off
title CASZONE X-TOOLS v4.3 (개발자:김인철)
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
echo Run as Administrator...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
set params = %*:"=""
echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
rem del "%temp%\getadmin.vbs"
exit /B
:gotAdmin
:MENU
c:
cd\
cls
echo.
echo ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
echo.
echo CASZONE X-TOOLS v4.3 (개발자:김인철)
echo.
echo ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
echo.
echo.
echo [1] 교체 전 - 기존 PC 에서 (백업)
echo.
echo [2] 교체 후 - 새 PC 에서 (복원)
echo.
echo [3] 프로그램 닫기
echo.
echo.
set /p choice= "진행 할 작업 번호를 입력하세요 : "
echo.
if "%choice%" == "1" goto :BEFORE
if "%choice%" == "2" goto :AFTER
if "%choice%" == "3" goto :END
goto MENU
echo.
:BEFORE
cls
echo.
echo.
echo 네트워크 정보 및 인증서를 백업 할 위치 선택하세요.
echo.
echo C 파티션을 제외한 드라이브를 지정하세요. 없으면 관리자에게 문의.
echo.
set /p DISK="디스크 드라이브 알파벳 d 또는 e 식으로 입력하세요. : "
echo.
echo.
echo 위에 선택한 경로를 재확인합니다. 맞은면 엔터!
echo ────────────────────────
echo.
set folder="%DISK%:\###CASZONE###"
set file="%folder%\_PRINTER_INFO.txt"
echo.
echo %folder%
echo.
echo %folder%\GPKI
echo.
echo %folder%\NPKI_program\NPKI
echo.
echo %folder%\NPKI_appdata\NPKI
echo.
pause
md "%folder%"
echo ─────────────────────────
echo 1 PC 교체 전 - 기존 PC 설정 값 확인
echo ─────────────────────────
echo.
echo 1-1 컴퓨터 이름, 윈도우 계정명 확인
echo.
wmic computersystem get "Name", "UserName"
wmic computersystem get "Name", "UserName" > %file%
echo.
echo 1-2 기존 PC본체 시리얼넘버 확인
echo.
wmic computersystem get "Model","Manufacturer"
wmic bios get serialnumber
wmic computersystem get "Model","Manufacturer" >> %file%
wmic bios get serialnumber >> %file%
echo.
echo ─────────────────────────
echo 2 프린터 IP 및 포트 정보, 공유 설정 확인
echo ─────────────────────────
wmic printer get "Name", "PortName", "ShareName"
wmic printer get "Name", "PortName", "ShareName" >> %file%
echo.
echo.
echo ─────────────────────────
echo 3 네트워크 IP (이더넷) 정보 확인
echo ─────────────────────────
echo.
for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b
set ip=%ip:~1%
echo IP address : %ip%
ipconfig /all > "%folder%\%ip%.txt"
echo.
echo.
echo.
echo ─────────────────────────
echo 4 기존 사용자 공인인증서 백업 작업
echo ─────────────────────────
echo.
echo.
echo.
md "%folder%\GPKI"
md "%folder%\NPKI_program\NPKI"
md "%folder%\NPKI_appdata\NPKI"
xcopy "%systemdrive%\GPKI" "%folder%\GPKI" /e /h /k /y
xcopy "%programfiles%\NPKI" "%folder%\NPKI_program\NPKI" /e /h /k /y
xcopy "%userprofile%\AppData\LocalLow\NPKI" "%folder%\NPKI_appdata\NPKI" /e /h /k /y
:: E 비어 있는 경우를 포함하여 디렉터리와 하위 디렉터리를 복사합니다.
:: H 숨겨진 파일과 시스템 파일도 복사합니다.
:: K 특성을 복사합니다. 일반적인 Xcopy는 읽기 전용 특성을 다시 설정합니다.
:: Y 기존 대상 파일을 덮어쓸지 여부를 묻지 않습니다.
md "%folder%\%DATE%\GPKI"
md "%folder%\%DATE%\NPKI_program\NPKI"
md "%folder%\%DATE%\NPKI_appdata\NPKI"
robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%systemdrive%\GPKI" "%folder%\%DATE%\GPKI"
robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%programfiles%\NPKI" "%folder%\%DATE%\NPKI_program\NPKI"
robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%userprofile%\AppData\LocalLow\NPKI" "%folder%\%DATE%\NPKI_appdata\NPKI"
echo.
echo.
pause
%SystemRoot%\explorer.exe /n, /e, "%folder%"
goto END
echo ========================================================================
:AFTER
c:
cd\
cls
echo.
echo.
echo ─────────────────────────
echo 1 사용자 인증서 복원
echo ─────────────────────────
echo.
echo.
echo 네트워크 정보 및 인증서를 복원 할 데이터 위치 선택하세요.
echo.
echo #CASZONE# 폴더가 있는 드라이브를 선택하세요.
echo.
set /p DISK2="디스크 드라이브 알파벳 d 또는 e 식으로 입력하세요. : "
echo.
echo.
echo 선택한 경로를 재확인합니다. 진행하려면 엔터!
echo ────────────────────────
echo.
set folder="%DISK2%:\###CASZONE###"
set file="%folder%\_PRINTER_INFO.txt"
echo.
echo %folder%
echo.
echo %folder%\GPKI
echo.
echo %folder%\NPKI_program\NPKI
echo.
echo %folder%\NPKI_appdata\NPKI
echo.
pause
echo.
echo.
SET /p qa="백업 된 인증서가 %folder% 폴더에 있나요? (Y/N) : "
if /i %qa%==y goto AFTERYES
if /i %qa%==n goto AFTER
goto AFTER
echo.
:AFTERYES
cls
md "%systemdrive%\GPKI"
md "%programfiles%\NPKI"
md "%userprofile%\AppData\LocalLow\NPKI"
xcopy "%folder%\GPKI" "%systemdrive%\GPKI" /e /h /k /y
xcopy "%folder%\NPKI_program\NPKI" "%programfiles%\NPKI" /e /h /k /y
xcopy "%folder%\NPKI_appdata\NPKI" "%userprofile%\AppData\LocalLow\NPKI" /e /h /k /y
echo.
echo 인증서 복사가 완료 되었습니다.
echo.
pause
echo.
goto NETWORK
:NETWORK
cls
echo.
echo.
echo ─────────────────────────
echo 2 새로운 PC 컴퓨터 정보 및 네트워크 IP 변경
echo ─────────────────────────
echo.
echo.
SET /p netqa="네트워크 IP 텍스트 파일이 %folder% 폴더에 있나요? (Y/N) : "
if /i %netqa%==y goto NETWORKYES
if /i %netqa%==n goto AFTER
goto AFTER
echo.
:NETWORKYES
cls
FOR /F "delims=" %%i IN ("%folder%\98*.txt") DO (SET filename=%%~ni)
ECHO %filename%
ECHO %filename:~0,5%
for /F "tokens=3,4 delims=. " %%a in ("%filename%") do (
set ipC=%%a
set ipD=%%b
)
echo %filename:~0,5%.%ipC%.%ipD%
goto StartConfig
:StartConfig
cls
REM ------------------------------------- Computer IP Setting -----------------------------------------------
SET IPx4=%filename%
SET SUBNETMASK=255.255.255.128
SET GATEWAY=%filename:~0,5%.%ipC%.1
SET DNS1=10.1.1.5
SET DNS2=168.126.63.1
SET NICName=이더넷
REM ---------------------------------------------------------------------------------------------------------
echo.
SET /p COMName="사용자 이름을 입력하세요 (컴퓨터 이름) : "
echo.
echo.
SET /p WorkGroup="부서(과)명을 입력하세요 (작업 그룹) : "
echo.
cls
echo.
echo.
ECHO 전체 컴퓨터 이름 : %COMName%
echo.
ECHO 작업 그룹 : %WorkGroup%
echo.
ECHO IP : %IPx4%
echo.
ECHO SUBNETMASTK : %SUBNETMASK%
echo.
ECHO GATEWAY : %GATEWAY%
echo.
ECHO DNS1 : %DNS1%
echo.
ECHO DNS2 : %DNS2%
echo.
echo.
goto QA
echo.
:QA
echo.
echo.
SET /p qa="설정 할 네트워크 값이 정확합니까? (1.예 / 2.아니요) 숫자 입력 : "
if /i %qa%==1 goto Exec
if /i %qa%==2 goto StartConfig
goto QA
echo.
:Exec
echo.
ECHO Starting Config....
echo.
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v Hostname /t REG_SZ /d %COMName% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d %COMName% > nul
ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d %COMName% > nul
echo.
echo.
echo 컴퓨터 이름이 %COMName% 으로 변경되었습니다.
echo.
echo.
ECHO 네트워크 IP 값 설정합니다.
echo.
netsh interface ip set address "%NICName%" static %IPx4% %SUBNETMASK% %GATEWAY% 1
echo.
ECHO 네트워크 DNS1 값 설정합니다.
echo.
netsh interface ip set dns name="%NICName%" source=static addr=%DNS1% register=PRIMARY
echo.
ECHO 네트워크 DNS2 값 설정합니다.
echo.
netsh interface ip add dns name="%NICName%" addr=%DNS2% index=2
echo.
echo.
wmic computersystem where name="%computername%" call joindomainorworkgroup name="%WorkGroup%"
echo.
wmic bios get serialnumber
wmic computersystem get "Model","Manufacturer"
wmic computersystem get "Name", "UserName"
wmic cpu get name
wmic os get name
wmic nicconfig get ipaddress,macaddress
echo.
echo.
echo.
echo 작업 그룹명을 %WorkGroup% 으로 변경, 재부팅 후 입력 값이 정확한지 확인하세요^^
echo.
echo.
echo.
pause
sysdm.cpl
goto END
echo.
:END
exit
echo.
-
No Image notice
CASZONE X-TOOLS Add-On v1.6.3
@echo off mode con:cols=65 lines=20 title CASZONE X-TOOLS Add-On v1.6.3 (개발자:김인철) >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" if '%errorlevel%' NEQ '0' ( echo Run as Administrat...Date2019.09.18 Category배치파일 Views2052 -
notice
CASZONE X-TOOLS v4.8.2
IP 대역 98.18 부분을 사용 할 사내망 IP 대역으로 변경하세요. RAM---Computer IP Setting 안에 SUBNETMASK, DNS1, DNS2 사내망 네트워크 정보로 수정하여 사용하세요. @echo off title CASZONE X-TOOLS v4.8 (개발자:김인철) >nul 2>&1 "%SYSTEMROOT%\s...Date2019.09.01 Category배치파일 Views1708 -
No Image
CASZONE X-TOOLS v4.3 (Win10, Win7)
네워크 정보는 사용자 환경에 맞게 수정하여 사용바랍니다. ----- Computer IP Setting ----- SET SUBNETMASK= 수정필요 SET GATEWAY= 수정 금지! SET DNS1= 수정필요 SET DNS2= 수정필요 SET NICName= 수정필요 @echo off title CASZONE X-TOOLS v4.3 (개발자...Date2019.09.01 Category배치파일 Views550 -
No Image
CMD 레지스트리 값 입력 (IMPORT) iexplore.exe
@echo off taskkill /f /im iexplore.exe /t REG IMPORT 레지스트리명.reg start iexplore.exe "about:Tabs"Date2016.10.21 Category배치파일 Views360 -
No Image
CompName
@echo off for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b set ip=%ip:~1% for /F "tokens=2 delims==" %%s in ('wmic bios get serialnumber /value') do set sn=%%s echo IP address : %ip% echo Computer S...Date2016.12.06 Category배치파일 Views452 -
No Image
IE RESET v2.3.4 (인터넷 익스플로러 초기화)
@echo off timeout.exe /t 5 echo. echo. Echo + 전원 구성표 : 고성능(활성) POWERCFG -SETACTIVE 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c echo. Echo + 디스플레이 끄기 : 해당없음 (0값) POWERCFG /Change /monitor-timeout-ac 30 echo. Echo + 다음시간이후...Date2019.03.23 Category배치파일 Views414 -
No Image
IE RESET v2.3.5 (인터넷 익스플로러 초기화)
@echo off timeout.exe /t 5 taskkill /f /im AdobeARM.exe /t taskkill /f /im HncCheck.exe /t taskkill /f /im veraport.exe /t taskkill /f /im delfino.exe /t taskkill /f /im I3GProc.exe /t taskkill /f /im AnySign4PC.exe /t taskkill /f /im stsess...Date2019.04.03 Category배치파일 Views715 -
No Image
ie_Toolbar_Uninstall_v5
@echo off goto MENU :MENU cls echo. echo. echo. echo [0] 모든 툴바/클리너 삭제 [6] 알(EST) 툴바 삭제 echo. echo [1] 네이버 클리너 삭제 [7] 그룹웨어 액티브X 삭제 echo. echo [2] 네이버 백신 삭제 [8] 탭서비스 URL 오류 수정 echo. echo [3] 네이버...Date2016.11.22 Category배치파일 Views385 -
No Image
mega_start_v1611-25
@echo off goto MENU :MENU cls echo. echo OA담당자 김인철 입니다. echo. echo. echo [1] DhtmlEd.ms 설치 echo. echo [2] PlusCcmsV4 설치 echo. echo [3] MegaBox_OCX_Setup (CTI) echo. echo [4] WineDownload 실행 echo. echo [5] echo. echo [0] CMD 창...Date2016.12.06 Category배치파일 Views287 -
No Image
mpc_start_v2
@echo off c: cd\ C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\desktop_clear.cmd C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\services_power_exit.cmd C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\systeminfo_mpc...Date2016.12.06 Category배치파일 Views269 -
No Image
mstsc_history_delete
@echo off echo. del "cd "%USERPROFILE%\Documents\Default.rdp" /a -h /f /q REG DELETE "HKEY_CURRENT_USER\Software\Microsoft\Terminal Server Client\Default" /F mstsc /v 192.168.4.89 echo. pauseDate2016.10.21 Category배치파일 Views312 -
No Image
OneDrive Delete Batch
@echo off >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" if '%errorlevel%' NEQ '0' ( echo Run as Administrator... goto UACPrompt ) else ( goto gotAdmin ) :UACPrompt echo Set UAC = Create...Date2021.04.28 Category배치파일 Views1739 -
No Image
pc_setting_v1
@echo off c: cd\ C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\CompName.cmd C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\services_power_exit.cmd C:\Windows\System32\CMD.exe /c start c:\temp\OA_install\systeminfo_local.cm...Date2016.12.06 Category배치파일 Views348 -
ROBOCOPY 나만의 파일 자동 백업 배치파일 만들기
두가지 파일을 만듭니다. 첫번째 파일 : backup.cmd ※파일확장자 CMD @echo off robocopy /MIR /XO /COPY:DAT /ZB /R:1 /W:1 "원본경로" "백업경로\%DATE%" msg * "%date% 백업완료" exit 두번째 파일 : auto.vbs ※파일확장자 VBS Set WinScriptHost = CreateO...Date2021.01.20 Category배치파일 Views2539 -
No Image
Start_Page
Windows Registry Editor Version 5.00 [HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main] "Start Page"="http://gw.jw-group.co.kr/"Date2016.11.22 Category배치파일 Views406 -
No Image
systeminfo_to_info
c: cd\ cls for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b set ip=%ip:~1% for /F "tokens=2 delims==" %%s in ('wmic bios get serialnumber /value') do set sn=%%s echo IP address : %ip% echo Computer ...Date2016.12.31 Category배치파일 Views286 -
No Image
systeminfo_to_info_COMPUTERNAME
c: cd\ cls for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b set ip=%ip:~1% for /F "tokens=2 delims==" %%s in ('wmic bios get serialnumber /value') do set sn=%%s echo IP address : %ip% echo Computer ...Date2017.01.11 Category배치파일 Views396 -
No Image
systeminfo_to_pc
c: cd\ cls copy "\\192.168.4.157\samba\OA_Administrator\_System_info\C_ROOT_CMD\Windows\Temp\cpuz\cpuz.ini" "C:\Windows\Temp\cpuz\" /y copy "\\192.168.4.157\samba\OA_Administrator\_System_info\C_ROOT_CMD\Windows\Temp\cpuz\7za.exe" "C:\Window...Date2016.12.31 Category배치파일 Views277 -
No Image
systeminfo_to_power
@echo off c: cd\ cls echo. echo. Echo + 전원 구성표 : 고성능(활성) POWERCFG -SETACTIVE 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c echo. Echo + 디스플레이 끄기 : 해당없음 (0값) POWERCFG /Change /monitor-timeout-ac 0 echo. Echo + 다음시간이후에 하드...Date2016.12.31 Category배치파일 Views270 -
No Image
systeminfo_to_samba
c: cd\ cls timeout 150 copy "\\192.168.4.157\samba\OA_Administrator\_System_info\C_ROOT_CMD\Windows\Temp\systeminfo.7z" "C:\Windows\Temp\" /y C:\Windows\Temp\cpuz\7za.exe e C:\Windows\Temp\systeminfo.7z -oC:\Windows\Temp\ -aoa -psysteminfo C...Date2016.12.31 Category배치파일 Views258